///////// Text Ghost Template
///////// Menu Processing Dictionary
///////// copyright (C) 2002 umeici.

//**** Expand main menu *************************************************************

//---- Expand main menu ---------------------------------------------------------------
OpenMenu
{
	"\1\s[10]\0%OpenMenuTalk\n\n[half]/
	\![*]\q[%(MENUITEM('Tell me something')),OnAiTalk]\n"
	--
		if LastTalk != ""
		{
			"\![*]\q[%(MENUITEM('I want to hear what you just said')),OnLastTalk]\n"
		}
	--
	"/
	\![*]\q[%(MENUITEM('Trivia')),ChoiceBeesknowledge]\n/
	\![*]\q[%(MENUITEM('Other')),ChoiceBeeworks]\n/
	\![*]\q[%(MENUITEM('Change frequency of talking')),ChoiceTalkInterval]\n/
	\![*]\q[%(MENUITEM('いっしょに過ごした時間')),ChoiceHanayu]\n/
	\![*]\q[%(MENUITEM('なんでもない')),ChoiceCancel]\e"
}

OpenMenuTalk
{
	"\s[0]Did you call meー？"
	"\s[1]Oh、what can I do for you？"
}

//---- Function to fill in spaces after menu items
MENUITEM
{
	_menuitem = _argv[0]
	for _i = GETSTRBYTES(_menuitem) ; _i < 27 ; _i++
	{
		_menuitem += " "
	}
	_menuitem
}


//---- OnChoiceSelect event -----------------------------------------------------------
//All OnChoiceSelect event functions start with Choice (so I can tell)
OnChoiceSelect
{
	EVAL(reference0)
}

//---- Anchor dictionary --------------------------------------------------
OnAnchorSelect
{
	EVAL(reference0)
}

//**** Menu item selection *****************************************************************

//----Other menus ---------------------------------------------------------
Modeetc
{
	"/
	\![*]\q[%(MENUITEM('Back')),OpenMenu]\e"
}


//---- Adjusting the talk frequency
ChoiceTalkInterval
{
	"\0\s[0]How much is good？\n\n/
	\q[%(MENUITEM('Loud')),ChoiceTalkMax]\n/
	\q[%(MENUITEM('Normal')),ChoiceTalkNormal]\n/
	\q[%(MENUITEM('Relaxed')),ChoiceTalkPoor]\n/
	\q[%(MENUITEM('Shut up')),ChoiceTalkNone]\e"
}

//---- Talk frequency
ChoiceTalkMax
{
	//---- Talk loudly (15 second intervals)
	aitalkinterval = 15
	"\0\s[9]Okay、let's get going。\e"
}

ChoiceTalkNormal
{
	//---- Speak normally (2 minute intervals)
	aitalkinterval = 120
	"\0\s[1]Just talk normally。\e"
}

ChoiceTalkPoor
{
	//---- Talk leisurely (5 minute intervals)
	aitalkinterval = 300
	"\0\s[0]Well、take it easy。\e"
}

ChoiceTalkNone
{
	//---- Don't talk
	aitalkinterval = 0
	"\0\s[3]Ehー・・・\w5\n\s[4]It's boring。\e"
}

//---- Replay previous conversation -------------------------------------------------------------------------
OnLastTalk
{
	"\0\s[0]Well・・・\w9\w9\w9\c/
	%LastTalk"
}

//---- Time spent together ---------------------------------------------------------
ChoiceHanayu
{
	"\0\s[0]A graph of startup times for one week is displayed。\w8\w8\![raise,OnCallHanayu]\n\nTo close the graph、\ndouble-click it。\e"
}



//---- Cancel ---------------------------------------------------------
ChoiceCancel
{
	"\0\s[4]Huh。\e"
	"\0\s[3]Huhー。\e"
}

//Cancel 2
ChoiceCancel1
{
	"\0\s[0]Got it。\e"
	"\0\s[0]Yes。\e"
}

//---- Menu selection timeout ---------------------------------------------------------
OnChoiceTimeout
{
	"\0\s[8]Make sure you choose carefullyー。\e"
}