///////// 文　ゴーストテンプレート
///////// マウス入力関連辞書

//**** 撫で反応 *************************************************************************

//---- OnMouseMoveイベント --------------------------------------------------------------
OnMouseMove
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側の撫で
		MouseMoveSakura
	}
	else
	{
		//---- kero側の撫で
		MouseMoveKero
	}
}

//---- 本体側の撫で反応 -----------------------------------------------------------------
MouseMoveSakura
{
	if reference4 != ""
	{
		//----どこかが撫でられている
		stroke++
		//---- 撫でられた量が一定量に達したら「なでられている」と判断
		if stroke >= 64
		{
			//---- 撫でられた。撫でられた部位を見てトークする
			if reference4 == "Head"
			{
				"\0\s[52]う、照れるよ〜。\e"
			}
			elseif reference4 == "Decco"
			{
				"\0\s[51]\w8\w8\w8\1……愉しそうだな。\w8\0\s[2]わ。\w8\nや、やめてよ%username。\e"
			}
			elseif reference4 == "Bust"
			{
				"\1\s[10]楽しんでいるところ悪いが、\w3俺の方が触り心地良いと思うぞ。"
				--
				"\0\s[71]なっ。\e"
				"\0\s[1]そんなこと\w8\w8ないよ。\e"
			}
			stroke = 0
		}
	}
	else
	{
		// 定義された部位はどこも撫でられていない
		stroke = 0
	}
}

//---- kero側の撫で反応 -----------------------------------------------------------------
MouseMoveKero
{
	//---- なし
}


//**** つつかれ反応 *********************************************************************

//---- OnMouseDoubleClickイベント -------------------------------------------------------
OnMouseDoubleClick
{
	//---- reference3を見て、本体側かkero側かを判断する
	if reference3 == 0
	{
		//---- 本体側のつつかれ
		MouseDoubleClickSakura
	}
	else
	{
		//---- kero側のつつかれ
		MouseDoubleClickKero
	}
}

//---- 本体側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickSakura
{
	//---- 顔つつかれ処理
	if reference4 == "Decco"
	{
		deccotsuki++
		//---- おでこつつかれ反応
		if deccotsuki >= 20
		{
			deccotsuki = 0

			"\0\s[7]Stop it, you idiotー！"
			username = "アホすけ"
		}
		else
		{
			"\0\s[71]Stop itーーっ。\e"
			"\0\s[72]Don't touch meーー！\e"
			"\1\s[10]You'll be red tomorrow。\0\s[3]No way・・・\e"
		}
	}
	else
	{
		//---- おでこ以外のつつきでメニュー展開
		OpenMenu
	}
}

//---- kero側のつつかれ反応 -------------------------------------------------------------
MouseDoubleClickKero
{
	//---- kero側のつつかれ処理
	"\1\s[10]Wait、there's someone out there who's more worth poking than me。\0\s[3]なっ。\e"
}