///////// Text Ghost Template
///////// Menu Processing Dictionary
///////// written by umeici.

//**** Expand main menu *************************************************************

//---- Expand main menu ---------------------------------------------------------------
OpenMenu
{
	"\0\s[0]"
	--
	"Yes、\w5\s[5]did you call me？"
	"Um……\w3\s[5]what's wrong？"
	"Eh？\w5\n\s[5]%username、\w3do you need me？"
	--
	"\n\n/
	\![*]\q[Can you tell me something？,AITALK]\n/
	\![*]\q[I just want to change some settings,SETTEI1]\n/
	\![*]\q[Communicate,COMMUNICATEOPEN]\n/
	\![*]\q[Nothing,CANCEL]\e"
}


//**** Menu item selection *****************************************************************

//---- OnChoiceSelect event -----------------------------------------------------------
OnChoiceSelect
{
	//---- Main menu
	if reference0 == "AITALK"
	{
		//---- Explicitly instruct AI talk to start
		OnAiTalk
	}
	elseif reference0 == "SETTEI1"
	{
		//---- Setting change menu.
		"\0\s[0]Hmm、\w4\s[5]what should I do？\w3\n\n"
		"\0\s[5]What should I do？\w5\n\n"
		--
		"\![*]\q[Change the chat frequency,TALKINTERVAL]\n/
		\![*]\q[Change the name,TEACHNAME]\n/
		\![*]\q[Remember birthday,BIRTHDAYINPUT]\n/
		\![*]\q[Introduce yourself,JIKOSHOKAI]\n/
		\![*]\q[Vanish command,VANISHSELECT]\n/
		\![*]\q[Communicate,COMMUNICATEOPEN]\n\n/
		\![*]\q[Nothing after all,CANCEL]\e"
	}
	elseif reference0 == "TEACHNAME"
	{
		//---- Start 「Learn name」
		teachusername = 1
		"\0\s[0]Hmm、\w4\s[5]okay, I'll put the box up now, so can you write your name without a title？\w4/
		\![open,communicatebox]\e"
	}
	//---- Title options
	elseif reference0 == "KEISYO1"
	{
		username = "%usernameさん"
		"\0\s[5]ほなら%usernameって呼ぶわ。\e"
	}
	elseif reference0 == "KEISYO2"
	{
		username = "%usernameくん"
		"\0\s[5]ほなら%usernameって呼ぶわ。\e"
	}
	elseif reference0 == "KEISYO3"
	{
		username = "%usernameちゃん"
		"\0\s[5]ほなら%usernameって呼ぶわ。\e"
	}
	elseif reference0 == "KEISYO4"
	{
		username = "%username様"
		"\0\s[5]ほなら%usernameって呼ぶわ。\e"
	}
	elseif reference0 == "KEISYO5"
	{
		username = "%usernameたん"
		"\0\s[5]ほなら%usernameって呼ぶわ。\e"
	}
	elseif reference0 == "KEISYO6"
	{
		"\0\s[0]…………\w4\s[2]そのままでええんか？\e"
	}
	elseif reference0 == "TALKINTERVAL"
	{
		//---- Adjusting talk frequency
		"\0\s[0]How much should I talk？\w5\n\n/
		\![*]\q[Loud,TALKMAX]\n/
		\![*]\q[Normal,TALKNORMAL]\n/
		\![*]\q[Quiet,TALKPOOR]\n/
		\![*]\q[Shut up,TALKNONE]\e"
	}
	elseif reference0 == "JIKOSHOKAI"
	{
		"\0\s[54]Please wait a little longer here……\w3\s[1]There are various things to prepare for……。\e"
		"\0\s[1]There are various things to prepare for, so please wait a little longer……？\e"
	}
	elseif reference0 == "BIRTHDAYINPUT"
	{
		//---- Start entering birthday?
		ChoiceBirthdayEntry
	}
	elseif reference0 == "VANISHSELECT"
	{
		"\0\s[54]I wish there was no instruction……。\w8"
		"\0\s[4]Please do it without any instructions, as if nothing had happened……。\w8"
		--
		"\n\n/
		\![*]\q[With instruction to vanish,VANISHON]\n/
		\![*]\q[Without instruction to vanish,VANISHOFF]\e"
	}
	elseif reference0 == "VANISHON"
	{
		vanishswitch = 1
		"\0\s[3]Seriously……。\e"
		"\\0s[4]Ugh……。\e"
	}
	elseif reference0 == "VANISHOFF"
	{
		vanishswitch = 0
		"\0\s[5]Now I have skin in the neck♪\e"
		"\0\s[55]This will save me。\e"
	}
	elseif reference0 == "COMMUNICATEOPEN"
	{
		//---- Communicate box open
		"\0\s[0]Yes、\w3\s[5]I'll put it out now？\w3/
		\![open,communicatebox]\e"
	}
	elseif reference0 == "CANCEL"
	{
		//---- Cancelled
		"\0\s[0]…………\w4\s[54]cancel, right？\e"
		"\0\s[0]Hmm、\w5cancel, right？\e"
	}
	//---- Talk frequency
	elseif reference0 == "TALKMAX"
	{
		//---- Talk loudly (30 second intervals)
		aitalkinterval = 30
		"\0\s[0]\s[58]I'm going to put all my energy into it！！\e"
		"\0\s[7]I'm gonna do it！！\e"
	}
	elseif reference0 == "TALKNORMAL"
	{
		//---- Talk normally (1 minute interval)
		aitalkinterval = 60
		"\0\s[0]Normally……\w4about 1 minute。\e"
		"\0\s[4]This normally is the most difficult part……。\e"
	}
	elseif reference0 == "TALKPOOR"
	{
		//---- 心peak quietly (every 3 minutes)
		aitalkinterval = 180
		"\0\s[54]Okay……\w3\s[4]I'm being a little quiet。\e"
		"\0\s[0]Is it better to be a little quieter？\e"
	}
	elseif reference0 == "TALKNONE"
	{
		//---- Don't talk
		aitalkinterval = 0
		"\0\s[0]…………\w4\s[54]I wish you'd just end it……。\e"
		"\0\s[4]Ugh……\w3it's better to just end it……。\e"
	}
	//---- Headline
	elseif reference0 == "HEADLINECANCEL"
	{
		//---- キャンセルされた
		"\0\s[0]Hmm、\w3then I'll cancel the headline。\e"
	}
}

//---- Menu selection timeout  ---------------------------------------------------------
OnChoiceTimeout
{
	"\0\s[7]Choose carefully！！\e"
	"\0\s[7]I can at least keep an eye on the time, right！？\e"
}