////////// Text Ghost template
////////// Start/End/Switch Talk Dictionary
///////// copyright (C) 2002 umeici.

OnGhostLoad : void
{
	// If birthday is empty, put in dummy numbers
	if userBD == ""
	{
		userBD = "3000,13,32"
	}

	FUNCTIONLOAD("hanayu.dll")
	
	Timermode = 0		// Initialize timer processing mode
	LastTalk         = ""	// Initialize previous conversation
}

起動共通スクリプト
{
	if basewarename != 'embryo' {
		'\_q\1\![set,alignmenttodesktop,free]\0\_q'
	}
	else {
		''
	}
}

//**** First startup *************************************************************************

//---- OnFirstBoot event --------------------------------------------------------------
OnFirstBoot
{
	//---- Initialize variables
	username         = "ユーザーさん"
	stroke           = 0	// For stroking judgment
	teachusername    = 0	// For remembering the username
	mikireflag       = 0	// For cutting off
	communicateratio = 0	// Communication start rate [%]
	
	起動共通スクリプト
	--
	//---- Check the Vanish count and determine whether it is a true first time
	if reference0 == 0
	{
		//---- Really the first time the app is started
		"\0\s[2808]\_w[1000]\1\s[10]\0\s[6]\w3・\w3・\w3・\w3・\w3・\w3・\w8\w8\n\n/
		\1\s[10]うむ、無事に着きました。\w5\n%selfname、仕事場です。目を開けなさい。\w8\w8/
		\0\s[0]\w9\w9\w9\s[2]えっ、\w5\w9\w9\s[21]ええっ？　\w9\w9何よここ？！\w5\n\s[4]狭いよー！　人間界ってこんなに小さかった？\n\n\w8\w8/
		\1\c\s[18]うーむ・\w3・\w3・\w5\nここは人間の使う「ぱそこん」の中です。\w5\n\n\s[12]間違えてしまったものは仕方が無い。\nここでなんとかしましょう。\w8\w8/
		\0\s[4]また、ドジやっちゃった\w3・\w3・\w3・\w8\w8\s[5]\cと、とにかく、自己紹介します。\w5\n\n/
		\s[0]私は、%selfname。新米の天使です。\w5\n\s[1]実は、あなたの守護天使として派遣されたんだけど、\w5\n\s[30]間違ってここへ来ちゃいました。\n\n\w8/
		\1\c\s[10]私の名は、%keroname。\w5\n%selfnameのお目付け役です。\n\n\w8\w8/
		\0\s[0]いろいろご迷惑をかけるかもしれませんが、\n\_sこれから、よろしくおねがいします。\_s/
		\x\0\s[5]あの、改めてお名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
	else
	{
		//---- First time launch after reinstallation
		"\0\s[2808]\_w[1000]\1\s[10]\0\s[6]\w3・\w3・\w3・\w3・\w3・\w3・\w8\w8\n\n/
		\1\s[10]うむ、無事に着きました。\w9\w9\w9\n\n/
		\0はーい。\n\n\s[0]\w9\w9\w9\s[2]えっ、\w5\w9\w9\s[21]ええっ？　\w9\w9またここ？！\n\n\w8\w8/
		\1\s[18]いけない。この調子じゃまた追い返されます。\w8/
		\0\s[8]もう、%reference0回も追い返されてるしねー。\w8/
		\1\s[10]\c\w1・\w1・\w1・\w9まあ、なんとかやりましょう。/
		\0\s[0]\cそうだね・・・\w5\nまた、よろしくお願いします。\x\0\s[5]あの、改めてお名前、教えてください。\![open,inputbox,OnInputUsername,-1]\e"
	}
}


//**** Normal startup ***********************************************************************

//---- OnBoot event -------------------------------------------------------------------
OnBoot
{
	起動共通スクリプト
	--
	// Greeting process
	挨拶
}

//---- Function to roughly check morning/afternoon/night, etc. -------------------------------------------
GetTimeSlot
{
	if hour >= 4 && hour <= 11
	{
		"朝"
	}
	elseif hour >= 12 && hour <= 14
	{
		"昼"
	}
	elseif hour >= 15 && hour <= 17
	{
		"日中"
	}
	elseif hour >= 18 && hour <= 21
	{
		"夜"
	}
	else
	{
		"深夜"
	}
}


//**** End *****************************************************************************

//---- OnClose event ------------------------------------------------------------------
OnClose
{
	"\1\s[10]Are you done？\w5\0"
	--
	_timeslot = GetTimeSlot
	if _timeslot == "朝"
	{
		//---- End in the morning
		"\s[0]Are you up all night？\w6\n\s[5]Goodnight。"
	}
	elseif _timeslot == "昼" || _timeslot == "日中"
	{
		//---- End in the afternoon/daytime
		"\s[5]See you later。"
		"\s[5]Goodbye。"
	}
	else
	{
		//---- End at night/midnight
		"\s[5]Goodnight。"
	}
	--
	"\-\e"
}


//**** Restoring from minimized state *****************************************************************

//---- OnWindowStateRestore event -----------------------------------------------------
OnWindowStateRestore
{
	"\1\s[10]Oh dear・・・\0\s[0]\e"
	"\0\s[4]Phewー、it's back。\1\s[10]Yep。\e"
}


//**** Shell switching **********************************************************

//---- シェルチェンジ開始 ---------------------------------------------------------------
OnShellChanging
{
	"\0\s[0]着替え中・・・\e"
}

//---- シェルチェンジ完了 ---------------------------------------------------------------
OnShellChanged
{
	"\0\s[5]%reference0シェルに替わりました。\w5\nどう、%username？\e"
}