///////// Text Ghost Template
///////// Menu Processing Dictionary
///////// copyright (C) 2002-2003 umeici.

//**** Expand main menu *************************************************************

//---- Expand main menu ---------------------------------------------------------------
OpenMenu
{
	"\0\s[0]"
	--
	"What、%username？"
	"Hmmー？"
	"What？"
	--
	"\n\n/
	\![*]\q[Just tell me something,OnChoiceAITALK]\n/
	\![*]\q[What was that god's profile？,OnChoiceKGJISYO]\n/
	\![*]\q[About acquaintances,OnChoiceCrctList0]\n/
	\![*]\q[Check out Ashihara Town's newsletter,OnChoiceKgPlace0]\n/
	\![*]\q[What Hikari can do,OnChoiceDEKIRU]\n/
	\n/
	\![*]\q[Next,OnChoiceMenu01]\n/
	\![*]\q[No・・・nothing。,OnChoiceMENUCANCEL]\e"
}
OnChoiceMenu01
{
	"\0\s[0]"
	--
	"What's that？"
	--
	"\n\n/
	\![*]\q[Change the pace of your speech,OnChoiceTALKINTERVAL]\n/
	\![*]\q[Change the way you call me,OnChoiceUSERKANRI]\n/
	\![*]\q[I have something to talk about,OnChoiceCOMMUNICATEOPEN]\n/
	\n/
	\![*]\q[Go back,OpenMenu]\n/
	\![*]\q[Nah・・・nothing。,OnChoiceMENUCANCEL]\e"
}

OpenMenu2
{
	"\1\s[10]Ｓｅｌｅｃｔ　ＳｕｂＭｅｍｕ\n\n/
	\![*]\q[Parameter check,OnChoiceParameter]\n/
	\![*]\q[Parameter initialization,OnChoiceSetParameter]\n/
	\![*]\q[Debug,OnChoiceDebag]\n/
	\![*]\q[No・・・nothing。,OnChoiceMENUCANCELkero]\e"
}
OnChoiceMENUCANCELkero
{
	"\1\s[10]Ｏ．Ｋ．\e"
}

//**** Menu item selection *****************************************************************

//---- OnChoiceSelectイベント -----------------------------------------------------------
//---- See Bunya's How to write OnChoiceSelect as an independent function (without if reference).
//---- For choice events, write "OnChoice" as a marker.
OnChoiceSelect
 {
 　CALLBYNAME(reference0)
 }

//---- Menu items ---------------------------------------------------------------------
//---- Main menu
OnChoiceAITALK
{
	//---- Explicitly instruct AI talk to start
	OnAiTalk
}

OnChoiceTALKINTERVAL
{
	//---- Adjusting the frequency of talk
	"\0\s[0]How much should I talk。\n\n/
	\![*]\q[Please talk like a machine gun （30秒）,OnChoiceTALKMAX]\n/
	\![*]\q[Normal is fine （2分30）,OnChoiceTALKNORMAL]\n/
	\![*]\q[Be quiet (4分),OnChoiceTALKPOOR]\n/
	\![*]\q[Just being there is fine,OnChoiceTALKNONE]\e"
}

OnChoiceCOMMUNICATEOPEN
{
	//---- Communicate box open
	"\0\s[0]What is it？\![open,communicatebox]\e"
}

OnChoiceCANCEL
{
	//---- Cancelled
	"\0\s[0]Hmm・・・。\e"
}

OnChoiceMENUCANCEL
{
	//---- Cancelled
	"\0\s[0]I see。\w6\n\s[5]Well、that's it。\w3\e"
}

OnChoiceMENUCANCEL2
{
	//---- SUB menu canceled
	"\1\s[10]・・・。\e"
}

OnChoiceUSERKANRI
{
	//---- Remember name
	teachusername = 1
	"Eh・・・\w6%username is not okay、\w4no？\n\w8/
	\nI understand。\w3What should I call you？\![open,communicatebox]\e"
}

//---- Talk frequency
OnChoiceTALKMAX
{
	//---- Talk loudly (30 second intervals)
	aitalkinterval = 30
	"\0\s[0]Okay！I'm going to talk！\e"
}

OnChoiceTALKNORMAL
{
	//---- Speak normally (2.5 minute intervals)
	aitalkinterval = 150
	"\0\s[0]Just normally。\w8Yeah、gotit。\e"
}

OnChoiceTALKPOOR
{
	//---- Speak quietly (4 minute intervals)
	aitalkinterval = 240
	"\0\s[6]Quiet、huh。\w4Yeah、I'll do that。\w6\nShall I go and make some tea？\e"
}

OnChoiceTALKNONE
{
	//---- Don't talk
	aitalkinterval = 0
	"\0\s[1]Yeah、I got it・・・・・・。\n\w8\s[1101]\nI guess this is okay too。\e"
}

//---- Headline
OnChoiceHEADLINECANCEL
{
	//---- Cancelled
	"\0\s[0]Oh、really？\e"
	"\0\s[0]What the heckー・・・。\e"
}

//---- Menu selection timeout ---------------------------------------------------------
OnChoiceTimeout
{
	"\0\s[7]Ugh・・・。\w4\nToo late！！\w8\nI'm asking you、so please choose carefully。\e"
}

//---- Additional menu ---------------------------------------------------------------------

//---- Additional function "What you can do" menu ---------------------------------------------------
OnChoiceDEKIRU
{
	"\0\s[53]That said、\w4there aren't that many。\w8\n/
		\s[0]\w4That's about it for now。\n\n/
	\![*]\q[View computer information,OnChoiceMachine]\n/
	\![*]\q[Recite a prayer,OnChoiceSayNolito]\n\n/
	\![*]\q[Please ask again next time,OnChoiceMENUCANCEL]\e"
}

//---- View computer information SAORI - Cupid ----
OnChoiceMachine
{
	os_name = FUNCTIONEX("saori_cpuid.dll","os.name")
	os_version = FUNCTIONEX("saori_cpuid.dll","os.version")
	os_build = FUNCTIONEX("saori_cpuid.dll","os.build")
	cpu_name = FUNCTIONEX("saori_cpuid.dll","cpu.name")
	cpu_clockex = FUNCTIONEX("saori_cpuid.dll","cpu.clockex")
	"\0Let's see？\w8\n/
	ＯＳは　%os_nameで\w6\n/
	ヴァージョンは　%os_version \w6\n/
	ビルド番号は　%os_build ね。\w8\w6\n/
	\n/
	ＣＰＵの名前は、%cpu_name 。\w6\n/
	ＣＰＵのクロック速度は、%cpu_clockex ＭＨｚだわ。\w8\w8\n"
	--
	//---- Comments on CPU speed
	if cpu_clockex >= 3000
	{
		"\s[2]That's amazing！\w8\s[0]\n%username、\w4are you making a movie or something？"
	}
	elseif cpu_clockex >= 2000
	{
		"Amazing\w3・\w3・\w3・\w4do you use it for design work？\w8\n"
	}
	elseif cpu_clockex >= 1000
	{
		"You can edit videos, right。\w8\n\s[51]Hey、\w3can I bring some videos from when you were little next time、\w4can I bring it？\w8\s[0]\n"
	}
	elseif cpu_clockex >= 433
	{
		"\s[53]Oh、I know a computer with this CPU speed・・・\w8\s[0]It can do a lot of things and the performance is plenty good、\w4yeah。\w8\s[0]\n"
	}	
	else
	{
		"It's a good computer。\w8\n"
	}
	--
	"・\w3・\w3・\w3\s[5]that's it！\w8\e"
}

//**** A mechanism for calling the OnAnchorSelect event with an independent variable ********************************
OnAnchorSelect
{
	CALLBYNAME(reference0)
}