///////// Text Ghost template
////////// Various event dictionaries
///////// copyright (C) 2002 umeici.

//**** Installation related *****************************************************************

//---- Messages during installation -------------------------------------------------------
OnInstallBegin
{
	"\0\s[0]Installing。\e"
}

//---- Installation completion message -------------------------------------------------------
OnInstallComplete
{
	"\0\s[0]"
	--
	if reference0 == "shell"
	{
		"シェル"
	}
	elseif reference0 == "ghost"
	{
		"ゴースト"
	}
	elseif reference0 == "balloon"
	{
		"バルーン"
	}
	elseif reference0 == "plugin"
	{
		"プラグイン"
	}
	--
	"「%reference1」、has been installed。"
	--
	if reference0 == "ghost"
	{
		Ghostname = reference1
		"/
		\nSubstitute？\n\n/
		\![*]\q[";--;MENUITEM("Nice to meet you");--;",ChoiceGhostchange0]\n/
		\![*]\q[";--;MENUITEM("No、later");--;",ChoiceGhostchange1]\e"
	}
	else
	{
		"\e"
	}
}

//Whether to switch ghosts
ChoiceGhostchange0
{
	"/
	\1\s[10]\cNow、I'll switch with %Ghostname。\w5\n/
	Sometimes it doesn't work、so\w5\n/
	If that happens, please switch manually。\w8/
	\0\s[5]See you later。\w9\w9/
	\![change,ghost,%Ghostname]\e"
}

ChoiceGhostchange1
{
	"\0\s[5]Yes。\e"
}

//---- Installation failure message -------------------------------------------------------
OnInstallFailure
{
	"\1\s[10]Installation failed。\n\nReason：%reference0。\0\s[4]Oh no。\e"
}

//---- Installation refused (archive for another ghost) -------------------------
OnInstallRefuse
{
	"\1\s[10]This is\n an archive for %reference0。\w6\0\s[4]Stop。\e"
}


//**** Disappearance related *************************************************************************

//---- Vanish command -------------------------------------------------------------------------
OnVanishSelecting
{
	"\0\s[3]Do you hate %selfname？\e"
}

//---- Vanish start -------------------------------------------------------------------------
OnVanishSelected
{
	"\0\s[3]Sniff\w5・\w5・\w5・\w5・\w5\nbye。\w5/
	\1\s[10]Let's meet again somewhere。\w9\w9\e"
}

//---- Vanish cancel -------------------------------------------------------------------------
OnVanishCancel
{
	"\1\s[10]Looks like you were saved。\w5/
		\0\s[5]Everyone makes mistakes。\e"
}

//---- Other ghosts vanished and replaced by me -----------------------------------------
OnVanished
{
	"\0\s[3]%reference0、poor thing・・・\n\n\w5\1\s[10]That might be what we'll be like tomorrow。\w5\0\s[3]Snif・・・\e"
}


//**** Check email *******************************************************************

//---- Start checking email ---------------------------------------------------------------
OnBIFFBegin
{
	"\0\s[0]Did you get a letter？\n%keroname、nice to meet you。\1\s[10]Okay。\e"
}

//---- Check email successfully ---------------------------------------------------------------
OnBIFFComplete
{
	if reference0 == 0
	{
		//---- No email
		"\1\s[10]No email。\w5\0\s[0]Thank youー。\e"
	}
	else
	{
		//---- Email arrived
		"\1\s[10]%reference0 emails。\w5\0\s[5]You got a letter。\e"
	}
}

//---- Check email failed ---------------------------------------------------------------
OnBIFFFailure
{
	if reference0 == "timeout"
	{
		//---- Timeout
		"\1\s[10]Timeout。\0\s[4]%username、timeout、they say。\e"
	}
	elseif reference0 == "kick"
	{
		//---- Kicked
		"\1\s[10]You got kicked。\0\s[4]%username、you got kicked。\e"
	}
	elseif reference0 == "defect"
	{
		//---- Setting error
		"\1\s[10]It's no good at all。\nPlease check your email check settings。\w5\0\s[4]Oh noー。\e"
	}
	else
	{
		//---- Cause unknown
		"\1\s[10]I don't know why、but it failed。\w5\0\s[4]Oh noー。\e"
	}
}


//**** Network update *****************************************************************

//---- ネットワーク更新開始 -------------------------------------------------------------
OnUpdateBegin
{
	if reference3 == "baseware"
	{
		"\0\s[25]ほんたいのねっとわーくこうしん、\nかいしします。\w5\1\s[10]何のことか理解してないな・・・\e"
	}
	else
	{
		"\0\s[25]ねっとわーくこうしん、かいしします。\w5\1\s[10]何のことか理解してないな・・・\e"
	}
}

//---- ネットワーク更新準備完了 ---------------------------------------------------------
OnUpdateReady
{
GetSender = REQ.VALUE("Sender")
Getfiles = reference0+1
	{
		if Getfiles >= 10
		{
			"\0\s[3]%keroname、たくさんあるんだって。\n\n\w8\1\s[10]急いでやろうな。\w5\0\s[0]うん。\e"
		}
		else
		{
			if GetSender == "NiseRingo"
			{
				"\0\s[0]あたらしいのは\w3\n%reference0こ。\e"
			}
			else
			{
				"\0\s[0]あたらしいのは\w3\n%Getfilesこ。\e"
			}
		}
	}
}

//---- ネットワーク更新終了 -------------------------------------------------------------
OnUpdateComplete
{
	if reference0 == "none"
	{
		//---- 更新すべきファイルが無かった
		"\1\s[10]更新は無し。\w5\0\s[4]にょあー。\e"
	}
	else
	{
		//---- 実際に更新が完了した
		"\1\s[10]更新完了〜。\w5\0\s[5]やったー。%movement_status\e"
	}
}

//---- ネットワーク更新失敗 -------------------------------------------------------------
OnUpdateFailure
{
	if reference0 == "timeout"
	{
		//---- タイムアウトした
		"\1\s[10]タイムアウト。\0\s[4]%username、たいむあうと、だって。\e"
	}
	elseif reference0 == "md5 miss"
	{
		//---- MD5値が一致しなかった
		"\1\s[10]MD5値が違ってましたぜ。\w5\0\s[4]にょあー。"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\1\s[10]%reference0、だって。\w5\0\s[4]うーん。"
	}
	--
	"\n\n\1\s[10]ネットワーク更新、失敗だ。\e"
}

//---- ネットワーク更新 ダウンロード開始 ------------------------------------------------
OnUpdate.OnDownloadBegin
{
	if Getfiles >= 10
	{
		"\_q\0\s[0]「%reference0」を、だうんろーど、します。\_q\e"
	}
	else
	{
		"\0\s[0]「%reference0」を、だうんろーど、します。\e"
	}
}

//---- ネットワーク更新 MD5値照合開始 ---------------------------------------------------
OnUpdate.OnMD5CompareBegin
{
	if Getfiles >= 10
	{
		"\_q\0\s[0]ちぇっく、はじめます。\_q\e"
	}
	else
	{
		"\0\s[0]ちぇっく、はじめます。\e"
	}
}

//---- ネットワーク更新 MD5値一致 -------------------------------------------------------
OnUpdate.OnMD5CompareComplete
{
	if Getfiles >= 10
	{
		"\_q\0\s[5]おっけー。\_q\e"
	}
	else
	{
		"\0\s[5]おっけー。\e"
		"\0\s[5]あってるよ。\1\s[10]うむ。\w"
	}
}

//---- ネットワーク更新 MD5値不一致 -----------------------------------------------------
OnUpdate.OnMD5CompareFailure
{
	"\1\s[10]MD5不一致！\0\s[4]にょあー。\e"
}

//**** Headline sense ***************************************************************

//---- Start headline sense -----------------------------------------------------------
OnHeadlinesenseBegin
{
	"\0\s[0]%reference0 Headline retrieval in progress。\e"
}

//---- Read headline -------------------------------------------------------------
OnHeadlinesense.OnFind
{
	//---- First line
	if reference2 == "First" || reference2 == "First and Last"
	{
		//---- First page
		"\0\b2\s[0]%reference0 headline、first page。"
	}
	elseif reference2 == "Next"
	{
		//---- A page in the middle
		"\0\b2\s[0]%reference0 headline、continued。"
	}
	elseif reference2 == "Last"
	{
		//---- The last page
		"\0\b2\s[0]%reference0 headline、this is the last one。"
	}
	--
	//---- Headline body
	"\n\n%reference3\n\n"
	--
	//---- Choices
	if reference2 == "First" || reference2 == "Next"
	{
		//---- If there is a next page
		"\![*]\q[";--;MENUITEM("Go to next page");--;",]\n/
		\![*]\q[";--;MENUITEM("I'll try it");--;",%reference1]\n/
		\![*]\q[";--;MENUITEM("I won't go");--;",ChoiceCancel]"
	}
	else
	{
		//---- If there is no next page
		"\![*]\q[";--;MENUITEM("I'll try it");--;",%reference1]\n/
		\![*]\q[";--;MENUITEM("I won't go");--;",ChoiceCancel]\e"
	}
}

//---- No headline update -------------------------------------------------------
OnHeadlinesenseComplete
{
	"\0\s[0]%reference0、no update。\e"
}

//---- Headline sense failure -----------------------------------------------------------
OnHeadlinesenseFailure
{
	"\1\s[10]Headline sense failed。\n\nReason："
	--
	if reference0 == "can't download"
	{
		"Download failed。"
	}
	elseif reference0 == "can't analyze"
	{
		"Headline analysis failed。"
	}
	else
	{
		"Mystery。"
	}
	--
	"\e"
}


//**** File creation related *****************************************************************

//---- updates2.dau作成開始 -------------------------------------------------------------
OnUpdatedataCreating
{
	"\0\s[0]あっぷでーたふぁいる、つくってます。\e"
}

//---- updates2.dau作成完了 -------------------------------------------------------------
OnUpdatedataCreated
{
	"\0\s[5]できました。\e"
}

//---- NAR作成開始 ----------------------------------------------------------------------
OnNarCreating
{
	"\0\s[5]なー。つくってます。\e"
}

//---- NAR作成完了 ----------------------------------------------------------------------
OnNarCreated
{
	"\0\s[5]「%reference0」の「なー」ふぁいる\n「%reference1」、できました。\e"
}

//****　時計合わせ　*********************************************************************
//**** みか (http://homepage2.nifty.com/ko-ki/) の辞書を参考にしました。感謝＞こーき氏

//----　時計合わせ開始 ------------------------------------------------------------------
OnSNTPBegin
{
	"\0\s[0]とけい、みてきます。\n%reference0 に、せつぞくちゅう。\e"
}

//----　時刻取得成功、比較開始 ----------------------------------------------------------
OnSNTPCompare
{
	SSNTP = reference1
	LSNTP = reference2
	"\0\s[0]\_qこっち：%LSNTP[1]月%LSNTP[2]日%LSNTP[3]時%LSNTP[4]分%LSNTP[5]秒。\_q\n/
	\_qむこう：%SSNTP[1]月%SSNTP[2]日%SSNTP[3]時%SSNTP[4]分%SSNTP[5]秒。\_q\n\n"
	--
	if reference3 == 0
	{
		"\s[5]うーん、ぴったり。\e"
	}
	else
	{
		"\0\n\s[0]%reference3びょう、ずれてます。\n\n/
		\q0[OnSNTPEXECUTE][じかんをあわせて]/
		\q1[OnSNTPCANCEL][そのままでいいよ]\e"
	}
}

//----　時計合わせ実行 ------------------------------------------------------------------
OnSNTPEXECUTE
{
	"\0\s[5]はい、あわせました。\6\e"
}

//----　時計合わせ中止 ------------------------------------------------------------------
OnSNTPCANCEL
{
	"\0\s[0]ちゅうしー。\e"
}

//----　時計合わせ失敗 ------------------------------------------------------------------
OnSNTPFailure
{
	"\0\s[4]しっぱいー。\e"
}


//**** そのほか *************************************************************************
//---- URLドロップ -----------------------------------------------------------

OnURLDropping
{
	"\0\s[0]\_q%reference0から、だうんろーど、してます。\_q\e"
}

OnURLDropped
{
	"\0\s[5]だうんろーど、できました。\e"
}

OnURLDropFailure
{
	if reference1 == "timeout"
	{
		//---- タイムアウトした
		"\1\s[10]タイムアウト。\0\s[4]%username、たいむあうと、だって。\e"
	}
	elseif reference1 == "artificial"
	{
		//---- ユーザー自身で中止
		"\0\s[0]ちゅうしー。\e"
	}
	else
	{
		//---- 上記以外の理由で失敗した
		"\1\s[10]%reference0、だって。\w5\0\s[4]しっぱいー。\e"
	}
}

//---- ファイルドロップ -----------------------------------------------------------
OnFileDrop2
{
	Filename = reference0
	_file = TOLOWER(Filename)
	//壁紙変更
	if ".png" _in_ _file || ".jpg" _in_ _file || ".jpeg" _in_ _file ||".bmp" _in_ _file
	{
		"/
		\0\s[5]かべがみに、する？\n\n[half]/
		\![*]\q[";--;MENUITEM("まんなかに");--;",ChoiceWallchange0]\n/
		\![*]\q[";--;MENUITEM("ならべて");--;",ChoiceWallchange1]\n/
		\![*]\q[";--;MENUITEM("かくだいする");--;",ChoiceWallchange2]\n/
		\![*]\q[";--;MENUITEM("やっぱりやめた");--;",CANCEL]\e"
	}
	//音楽再生
	elseif ".mid" _in_ _file || ".mp3" _in_ _file || ".wav" _in_ _file || ".wma" _in_ _file ||  ".au" _in_ _file || ".ogg" _in_ _file
	{
		FUNCTIONEX("mciaudior.dll","stop")
		FUNCTIONEX("mciaudior.dll", "load", "%Filename")
		"\0\s[5]\![raise,OnPlayMusic]音楽ふぁいる、さいせいちゅう。\w5\n\s[5]止めたいときは、%keronameのあたまを\nダブルクリックしてね。\e"
	}
}


ChoiceWallchange0
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "0")
	"\0\s[5]かべがみに、しました。\e"
}

ChoiceWallchange1
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "1")
	"\0\s[5]かべがみに、しました。\e"
}

ChoiceWallchange2
{
	_i = FUNCTIONEX("proxy.dll", "set_wall_paper.exe", "%ASC(34)%Filename%ASC(34)", "2")
	"\0\s[5]かべがみに、しました。\e"
}

//---mciaudior.dll呼び出し、開放------------

OnPlayMusic
{
	FUNCTIONEX("mciaudior.dll", "play")
}

OnStopMusic
{
	FUNCTIONEX("mciaudior.dll", "stop")
}

//---- 呼び名選択 -----------------------------------------------------------

//---- 質問
ChoiceUsernameEntry
{
	"\0\s[0]うーんと・・・\n\n/
	\![*]\q[";--;MENUITEM("「お父さん」と呼んでね。");--;",Gender4]\n/
	\![*]\q[";--;MENUITEM("「お兄ちゃん」だよ。");--;",Gender5]\n/
	\![*]\q[";--;MENUITEM("「お母さん」と呼んでね。");--;",Gender6]\n/
	\![*]\q[";--;MENUITEM("「お姉ちゃん」だよ。");--;",Gender7]\e"
}

//----性別
Gender0
{
	Gender = 0
	username = "おとうさん"
	"\_w[420]\0\s[5]おとうさん\w8・・・？\w5\n\s[1]わーい！\w5\n\nおとうさん、おとうさん！\w8\w8\1\s[10]よかったな。\e"
}

Gender1
{
	Gender = 0
	username = "おにいちゃん"
	"\_w[420]\0\s[5]おにいちゃん？\w8・・・\s[1]おにいちゃん！\w8\w8\1\s[10]よかったな。\e"
}

Gender2
{
	Gender = 1
	username = "おかあさん"
	"\_w[420]\0\s[5]おかあさん？\w8・・・\s[1]おかあさん！\w8\w8\1\s[10]よかったな。\e"
}

Gender3
{
	Gender = 1
	username = "おねえちゃん"
	"\_w[420]\0\s[5]おねえちゃん？\w8・・・\s[1]おねえちゃん！\w8\w8\1\s[10]よかったな。\e"
}

//----消滅指示後の性別
Gender4
{
	Gender = 0
	username = "おとうさん"
	"\_w[420]\0\s[0]おとうさん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender5
{
	Gender = 0
	username = "おにいちゃん"
	"\_w[420]\0\s[5]おにいちゃん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender6
{
	Gender = 1
	username = "おかあさん"
	"\_w[420]\0\s[5]おかあさん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}

Gender7
{
	Gender = 1
	username = "おねえちゃん"
	"\_w[420]\0\s[5]おねえちゃん\w8・・・？\w8\w8\1\s[10]うむ。\e"
}



//---- ディスプレイ解像度変更 -----------------------------------------------------------
OnDisplayChange
{
	//---- 変数にディスプレイ解像度と色深度に関する情報を取得
	//---- 使うかどうかは分からないがとりあえず保持しておく
	displaybpp    = reference0
	displaywidth  = reference1
	displayheight = reference2
}

//---- 花柚呼び出し ---------------------------------------------------------------
OnCallHanayu
{
	FUNCTIONEX("hanayu.dll", "show")
}

OnReleaseHanayu
{
	FUNCTIONEX("hanayu.dll", "hide")
}

//---- ごみ箱を空にする -----------------------------------------------------------
ChoiceGarbagecan
{
	"\0\t\s[5]ごみすて、いってきまーす。\w9\w9\s[-1]\b[-1]\![raise,OnGarbagecanEmpty]\_w[2500]\c\s[5]ただいまー\e"
}

OnGarbagecanEmpty
{
	_gomi = FUNCTIONEX("gomi.dll", "-f")
}